Actor lijsten

From Knowledge Graph Kunstenpunt

De Gouden Gids

We willen aan de hand van deze databank een overzicht maken van actoren in de Vlaamse kunstensector. We definiëren daarover een aantal categorieën, die niet scherp omlijnd zijn, maar die tot op zekere hoogte tegemoet komen aan de zoeknoden van mensen actief in de kunstensector. Welke organisatoren geven toonkansen? Waar kan ik terecht voor repetitieruimte?

We identificeerden deze categorieën:

  • Terugkerende toonkansen
  • Omkadering
    • Boekings-, management- en spreidingskantoren (PK)
    • Ondersteunende organisaties (MU)
    • Productieplatform (PK)
    • Producenten en agenten (BK)
    • Producenten (MU)
  • Maken
    • Artist-run collectieven (PK)
    • Projectruimtes (BK)
    • Labs voor hedendaagse muziek (MU)
    • Werkplaatsen en repetitieruimtes (PK)
    • Werkplaatsen en ateliers (BK)
    • Werkplaatsen en repetitieruimtes (MU)
  • Bijleren en ontwikkelen
    • Opleidingen, stages, masterclasses, onderwijs en vorming (MU)
    • Opleidingen (PK)
    • Opleidingen, postgraduaat (BK)
    • Residentieprogramma's (PK)
    • Residentieprogramma's (BK)
    • Residentieprogramma's (MU)
  • Publiceren
    • Theatertekstuitgeverijen (PK)
    • Kunstboekuitgeverijen (BK)
    • Partituuruitgeverijen (MU)
  • Over kunsten
    • Reflectieplatformen (PK)
    • Periodieke publicaties (BK)
    • Publicaties en media (MU)
  • Link naar het publiek
    • Participatie (PK)
    • Sociaal-artistieke kunstenorganisaties (BK)
    • Participatie (MU)
    • Jonge publieken (PK)
    • Jonge Publieken (MU)
    • Jonge Publieken (BK)

Technisch

PREFIX kp:<https://kg.kunsten.be/entity/>
PREFIX kpt:<https://kg.kunsten.be/prop/direct/>
PREFIX kpp:<https://kg.kunsten.be/prop/>
PREFIX kppq:<https://kg.kunsten.be/prop/qualifier/>
PREFIX kpps:<https://kg.kunsten.be/prop/statement/>
PREFIX wd: <http://www.wikidata.org/entity/>
PREFIX wdt: <http://www.wikidata.org/prop/direct/>

SELECT DISTINCT ?item ?itemlabel ?gps
  (Group_Concat(distinct ?agenttypeLabel; separator=", ") AS ?agenttypelbls) 
  (Group_Concat(distinct ?disciplineLabel; separator=", ") AS ?disciplinelbls)
  (Group_Concat(distinct ?url; separator=", ") AS ?urls)
  (Group_Concat(distinct ?media; separator=", ") AS ?medias)
  (Group_Concat(distinct ?text; separator=", ") AS ?texts)
  (Group_Concat(distinct ?wikidata; separator=", ") AS ?wikidatas)

WHERE {
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl" . }
  ?agenttype kpt:P1 kp:Q1472982.
  ?item kpt:P41 ?agenttype.
  ?item rdfs:label ?itemlabel.
  ?agenttype rdfs:label ?agenttypeLabel.
  OPTIONAL{
    ?item kpt:P8 ?discipline.
    ?discipline rdfs:label ?disciplineLabel
  }
  OPTIONAL{
    ?item kpp:P26 ?urlstatement.
    FILTER NOT EXISTS {?urlstatement kppq:P27 kp:Q58527.}
    ?urlstatement kpps:P26 ?url.
  }
  OPTIONAL{
    ?item kpt:P71 ?media.
  }
  OPTIONAL{
    ?item kpp:P78 ?textstatement.
    ?textstatement kppq:P79 kp:Q1446474.
    ?textstatement kpps:P78 ?text.
  }
  OPTIONAL{
    ?item kpt:P75 ?wikidata.
    BIND(URI(CONCAT(STR(wd:), ?wikidata)) AS ?wd)
    SERVICE <https://query.wikidata.org/sparql> {
      ?wd wdt:P625 ?gps.
    }
  }
}

GROUP BY ?item ?itemlabel ?gps
ORDER BY ASC(?itemlabel)